Creopard header Logo

Unterstüzen Sie dieses Projekt mit Ihrer Spende

Herzlichen Glückwunsch,

Ihr Werbeblocker funktioniert!

Bitte deaktivieren Sie Ihren Werbeblocker für diese Seite,
um kostenlose Dienste weiterhin zu ermöglichen.

Deutsche MS-DOS 6.22 Bootdiskette mit EMS + XMS + Netzwerk + FTP-Server

Zuletzt geändert: 07.12.2021 | Tags: , , |

Nach dem Erfolg der deutschen Windows 98 SE Bootdiskette legen wir hier noch mit einer deutschen MS-DOS 6.22 Bootdiskette nach.

Diese Bootdiskette stellt neben einem Bootmenü für XMS und EMS Speicherkonfigurationen und möglichst viel freiem konventionellem Speicher auch ein Beispiel für ein kleines Netzwerk bzw. einen FTP-Server auf dem Retro-PC (z.B. einen 486DX2-66) bereit, um den Datenaustausch zu erleichtern.

Das Projekt mTCP macht das Netzwerk-Setup relativ einfach:
Hat man einen Router wie die FritzBox im Netz, holt sich der PC automatisch eine IP-Adresse und der FTP-Server ist damit erreichbar. Nur den dazu notwendigen "DOS Packet Driver" für die Netzwerkkarte muss man sich vom Netzwerkkartenhersteller noch besorgen. (Im Downloadpaket liegt aktuell nur ein Packetdriver für eine 3Com 3C509B ISA Netzwerkkarte bei.)


Anmerkung: Ansätze unter MS-DOS mit dem "MS Client 3.0", der mit SMB1 Netzwerk-Freigaben umgehen könnte, stellten sich heutzutage als unpraktikabel heraus, da die anderen Systeme neben SMB1 sicherheitstechnisch noch weiter nach unten aufgeweicht werden müssten, Stichwort "LANMAN1".
Wer es dennoch versuchen möchte findet im os2museum.com eine gute Anleitung.

Datum
30.11.2020
Details
icon

Eine Bootdiskette für MS-DOS 6.22 mit Bootmenü, basierend auf einer damals von winfuture.de zur Verfügung gestellten englischen(!) MS-DOS Bootdiskette. Diese wurde dabei als Ausgangsbasis benutzt und verbessert.

Achtung: MS-DOS 6.22 kann keine Laufwerke/Partitionen lesen, die mit FAT32 formatiert wurden!

Folgende Konfiguration für sich für einen betagteren Intel 80486 DX2-66 bewährt:

dos_memory

  • Bootmenü: XMS + EMS + Netzwerk (mTCP) + ohne alles
  • HIMEM.SYS: Version 3.95 statt 3.10, alternativ XMGR.SYS als HIMEM.SYS Ersatz
  • EMM386.EXE: Version 4.95 statt 4.49
  • MOUSE.COM: MS-MOUSE v6.24, alternativ ctm-de21.exe (v2.1 beta4) oder ctm-de20.exe (v2.0 alpha 4)
  • KEYB2.COM: deutsches Tastaturlayout
  • DOSKEY.COM: erweitertes DOSKEY
  • CD/DVD Treiber: XDVD2.SYS, alternativ: MTMCDAI.SYS oder VIDECDD.SYS
  • MSCDEX v2.25 für beste Kompatibilität
  • UNISOUND.COM: Unisound v0.77a konfiguriert ISA-Soundkasten automatisch anhand der BLASTER-Variable
  • SMARTDRIVE: optionaler Festplatten Cache
  • Netzwerk:
  • Packet Driver für 3COM 3C509B ISA Netzwerkkarte
  • Packet Driver für REALTEK 8019AS RTL8019AS ISA Netzwerkkarte
  • mTCP (DHCP + FTP-Server): User/Pass: "dos"
  • Optional:
  • QBASIC + GORILLA.BAS ;-)
  • Tools:
  • CDBQ: CD Bremse/Slowdown
  • EMSMAGIC: für EMS Speicher (als Ersatz für EMM386.EXE)
  • IDEINFO: Festplatteninfo
  • MOUSETST.COM: Maus Testprogramm
  • TEST-SBP.EXE: Soundblaster (Pro) Testprogramm
  • UMBINFO.COM: Anzeige der Speicherbelegung des UMB
  • VESAINFO.EXE: Zeigt VESA Modus der Grafikkarte an
  • FIXMPU: SB16 Tool zur Behebung des "hanging notes bug"
  • JOYTEST: Joystick Check v1.05
  • WHATIDE: Festplatteninfo

Auszug der "Config.sys"

[MENU]
menuitem=XMS, (XMS + Maus + CD + Sound)
menuitem=EMS, (EMS + Maus + CD + Sound)
menuitem=NW, (XMS + Maus + Netzwerk + DHCP + FTP-SERVER)
menuitem=OHNE, (Nur konventioneller Speicher)
menudefault=XMS,10

[COMMON]
;Uebergeht die Verzoegerungszeit zum Ueberpruefen ob F5/F8 gedrueckt wurde, bevor die config.sys ausgefuehrt wird
SWITCHES=/F

;DOS in den hohen Speicherbereich laden + Upper Memory Blocks aktivieren
DOS=HIGH,UMB

;HIMEM.SYS (Version 3.95)
DEVICE=HIMEM.SYS /NUMHANDLES=128 /TESTMEM:OFF

;statt HIMEM.SYS kann auch XMGR.SYS benutzt werden (XMGR.SYS unterstuetzt mehr als 512 MB RAM)
;XMGR.SYS /B funktioniert nur mit UMBPCI.SYS (Chipsatzabhaengig)
;XMGR.SYS funktioniert nicht mit Quake, wenn bei EMM386.EXE "I=b000-b7ff" gesetzt wird.
;DEVICE=XMGR.SYS

;Anzahl der Dateien, die gleichzeitig geoeffnet werden koennen, je hoeher, desto mehr Speicher wird belegt
FILES=40

;Speicher fuer Festplatten Buffer bereitstellen,je hoeher, desto mehr Speicher wird belegt
BUFFERS=30

;Letzter moeglicher Buchstabe bei Laufwerken (bis Z), je hoeher, desto mehr Speicher wird belegt
LASTDRIVE=F ;Alte FCBS Unterstuetzung deaktivieren FCBS=1,0 ;DOS STACKS ;fuer Win 3.11 "STACKS=9,256" setzen und DEVICEHIGH=C:\WINDOWS\IFSHLP.SYS angeben ;Benutze MS-DOS Default von 9,128 fuer beste Kompatibilitaet, alternativ ist auch komplette Deaktivierung der STACKS moeglich mit (spart ca. 2Kb konventionellen Speicher): ;STACKS=0,0 ;EMM386.EXE Optionen (Version 4.95): ;I=b000-b7ff = unbenutzter Speicher bei Monochrome Video Memory ;I=b000-b7ff nicht mit XMGR.SYS verwenden (siehe oben) ;I=f000-f7ff = unbenutzter Speicher ;NOTR = Token Ring Adapter Erkennung deaktivieren ;D=64 = Gibt an, wie viele Kilobyte Speicher fuer DMA reserviert werden sollen. (Standard 32) ;HIGHSCAN = EMM386 soll eine zusaetzliche Kontrolle verwenden, um festzustellen, ob hoher Speicher als UMB oder Windows-EMS verwendet werden kann ;NOEMS = Ermoeglicht den Zugriff auf den hohen Speicherbereich (UMB) ;verhindert jedoch den Zugriff auf Expansionsspeicher (EMS). ;Parameter EMS UMB ;(ohne) maximal nein ;512 512 kb nein ;512 RAM 512 kb ja ;NOEMS nein ja [XMS] ;in VMware ohne Parameter "I=f000-f7ff" ausführen! ;DEVICE=EMM386.EXE NOEMS HIGHSCAN D=64 NOTR ;DEVICE=EMM386.EXE NOEMS HIGHSCAN I=b000-b7ff I=f000-f7ff D=64 NOTR
DEVICE=EMM386.EXE NOEMS HIGHSCAN I=b000-b7ff D=64 NOTR INCLUDE XHDD INCLUDE CD [EMS] ;in VMware ohne Parameter "I=f000-f7ff" ausführen! ;RAM 16384 = Limit auf maximal 16 MB RAM EMS (z.B. notwendig bei Wing Commander Privateer) ;DEVICE=EMM386.EXE RAM 8192 HIGHSCAN I=b000-b7ff I=f000-f7ff D=64 NOTR DEVICE=EMM386.EXE RAM 8192 HIGHSCAN I=b000-b7ff D=64 NOTR
INCLUDE XHDD INCLUDE CD [NW] DEVICE=EMM386.EXE NOEMS HIGHSCAN D=64 NOTR INCLUDE XHDD [XHDD] ;XHDD.SYS als SMARTDRV.EXE Ersatz: hier Cache mit 5 MB (/S5) ;und ggf. ohne UDMA (/E) fuer 486er, (/H) fuer upper memory ;XHDD cached auch Laufwerk A:, somit wird bei "DIR" immer wieder der gleiche Inhalt angezeigt ;DEVICEHIGH=XHDD.SYS /S5 /H ;mit 5MB cache (default 20 MB)! [CD] ;XDVD2.SYS universeller MS-DOS Modus IDE/ATAPI CD/DVD Treiber ;mit CD-Audio Unterstuetzung ;funktioniert mit XTIDE DEVICEHIGH=XDVD2.SYS /D:OPTICAL ;Muss wegen Caching nach XHDD.SYS geladen werden ;MTMCDAI.SYS als Alternative ;wahrscheinlich mit CD-Audio Unterstuetzung ;funktioniert mit XTIDE ;DEVICEHIGH=MTMCDAI.SYS /D:OPTICAL ;VIDECDD.SYS als Alternative mit "GR" (=deutsch) als Ausgabesprache ;funktioniert debingt mit XTIDE - MSCDEX benoetigt ewig zum Initialisieren ;DEVICEHIGH=VIDECDD.SYS /D:OPTICAL /L:GR ;OAKCDROM.SYS als Alternative ;funktioniert *NICHT* mit XTIDE ;DEVICEHIGH=OAKCDROM.SYS /D:OPTICAL [OHNE]

Auszug der "Autoexec.bat"

@ECHO OFF
PROMPT $p$g
PATH=A:\

rem deutsches Tastaturlayout
LH KEYB2.COM

rem Enhanced DOSKEY.com von http://www.paulhoule.com/doskey/
LH DOSKEY.COM

rem je nach gewaehlter Option im Menue, zur entsprechenden Konfiguration springen
GOTO %config%

:XMS
rem CD-ROM Treiber: MSCDEX v2.25 für beste Kompatibilitaet
rem /D:X nennt die Kennung der Angabe aus der Config.sys
rem /M:n bestimmt die Anzahl der Sektoren Buffer
rem /E bestimmt die Nutzung des erweiterten Speichers (EMS), falls dieser eingerichtet wurde
LH MSCDEX.EXE /D:OPTICAL /M:12

rem ALTERNATIV: SHSUCDX.COM laedt sich selbst automatisch in den hohen Speicherbereich, falls verfuegbar
rem SHSUCDX.COM /D:OPTICAL

rem SMARTDRIVE mit 4MB Cache nach MSCDEX laden, um das CD-ROM zu cachen, Floppy A+B nicht cachen
rem auf Laufwerk C: wird der Schreibpuffer aktiviert
rem LH SMARTDRV.EXE 4096 A- B- C+

GOTO MOUSE
GOTO SOUND
GOTO ENDE

:EMS
rem optional, Treiber fuer EMS Speicher (Ersatz für EMM386.EXE)
rem CD TOOLS
rem EMSMAGIC.EXE

rem ALTERNATIV: emsmagic.exe in autoexec.bat, statt "DEVICE=EMM386.EXE RAM" in config.sys
rem EMSMagic emulates EMS completely in software using extended memory (XMS).
rem Unlike EMM386, EMS Magic does not use Virtual 8086 (V86) mode to enable
rem hardware paging. Instead, data is copied to and from the page frame with XMS
rem EMSMAGIC.EXE

rem CD-ROM Treiber: MSCDEX v2.25 für beste Kompatibilitaet
rem /D:X nennt die Kennung der Angabe aus der Config.sys
rem /M:n bestimmt die Anzahl der Sektoren Buffer
rem /E bestimmt die Nutzung des erweiterten Speichers (EMS), falls dieser eingerichtet wurde
LH MSCDEX.EXE /D:OPTICAL /M:12 /E

rem ALTERNATIV: SHSUCDX.COM laedt sich selbst automatisch in den hohen Speicherbereich, falls verfuegbar
rem SHSUCDX.COM /D:OPTICAL

rem SMARTDRIVE mit 4MB Cache nach MSCDEX laden, um das CD-ROM zu cachen, Floppy A+B nicht cachen
rem auf Laufwerk C: wird der Schreibpuffer aktiviert
rem LH SMARTDRV.EXE 4096 A- B- C+

GOTO MOUSE
GOTO SOUND
GOTO ENDE

:NW
rem Netzwerkkarten initialisieren

rem Packet Driver fuer REALTEK 8019AS RTL8019AS ISA NIC
rem CD RTL8019
rem PNPPD.COM

rem Packet Driver fuer 3COM 3C509B ISA NIC
CD 3C509B
3C5X9PD.COM 0x60

rem pruefen, ob mtcp bereits existiert
IF NOT EXIST C:\MTCP\sample.cfg XCOPY A:\MTCP\*.* C:\MTCP\*.* /y
rem mTCP DHCP starten und FTP-SERVER initialisieren. USER/PASSWORT = "dos", siehe ftppass.txt
SET MTCPCFG=C:\MTCP\sample.cfg
C:\MTCP\dhcp.exe
echo FTP-SERVER in C:\MTCP\ftpsrv.exe
CD C:\MTCP

GOTO ENDE

:OHNE
GOTO ENDE

:MOUSE
rem MS-Maustreiber V6.24 fuer DOS von 1988, belegt nur ca. 10K
rem fuer beste Kompatibilitaet
LH MOUSE.COM

rem ALTERNATIV: Maustreiber CuteMouse v2.0 alpha 4 (de)
rem V2.0 branch uses direct hardware access for PS/2 mice, and supports the wheel.
rem V2.0 funktioniert nicht in VMware
rem LH CTM-DE20.EXE /R2

rem ALTERNATIV: Maustreiber CuteMouse v2.1 beta4 (de)
rem V2.1 branch uses BIOS to handle PS/2 mice but also supports the wheel, combining the best of V1.9 and V2.0.
rem LH CTM-DE21.EXE /R2

:SOUND
rem Setzen der BLASTER-Variable für SoundBlaster (+ kompatible Karten)
rem hier z.B. fuer Terratec Gold 16/96 (ESS1868F)
SET BLASTER=A220 I5 D1 H5 P330 T4 J201

rem hier z.B. fuer SB16 Value PnP
rem SET BLASTER=A220 I5 D1 H5 P330 T6 J201

rem A220 = Port Addresse (hier 220, alternativ: 240, 260)
rem I5   = Interrupt, IRQ (hier 5, alternativ: 7)
rem D1   = DMA channel 8 bit (hier 1, alternativ: 0, 3)
rem H5   = DMA channel 16 bit (hier 5, alternativ: 7)
rem P330 = Midi port (hier 330, alternativ: 300)
rem E620 = Port des EMU8000 Chips der AWE32, meist 620 
rem T6   = Typ der Soundblaster Karte (hier 6, alternativ:
rem  1   = SoundBlaster 1.0/1.5/MicroChannel (22kHz,  8bit, mono) 
rem  2   = SoundBlaster Pro 1.0 (dual-OPL2)  (44kHz,  8bit, mono oder 22KHz, 8bit, stereo)
rem  3   = SoundBlaster 2.0/2.0 CD/2.5       (44kHz,  8bit, mono)
rem  4   = Soundblaster Pro 2.0 (OPL3)       (44kHz,  8bit, stereo)
rem  5   = Soundblaster Pro 2.0 Microchannel (44kHz,  8bit, stereo)
rem  6   = SoundBlaster 16/32/AWE32/AWE64    (44kHz, 16bit, stereo)
rem J201 = Joystick Port Addresse (hier 201, alternativ: 200; "J0" deaktivert Port)

rem Unisound v0.77a konfiguriert ISA-Soundkarten automatisch anhand der BLASTER-Variable
UNISOUND.COM

:ENDE
rem CLS
Kategorie
Dateiname
Bootdisk für MS-DOS 6.22.exe
Größe
1 MB




Ähnliche Artikel anzeigen: